/*                                                                              
                                                                                
Generalized routine to dump environment in web server                           
                                                                                
*/                                                                              
signal on syntax                                                                
address command                                                                 
                                                                                
'PIPE REXXVARS 1 |' ,                                                           
  'take 1 |' ,                                                                  
   'var cmdline'                                                                
                                                                                
Parse var cmdline . platform callmethod fn ft fm ifn iaddress .                 
                                                                                
oft = 'REXXVARS'                                                                
ofm = 'W' /* marist default writeable - aka common */                           
                                                                                
'PIPE VAR path_translated 1 | var path_translated'                              
/*                                                                              
If 'CGI#' = substr(fn,1,4) then do                                              
  'PIPE VAR cgi 1 | var cgi'                                                    
   If cgi = 'CGI' then do                                                       
      'PIPE VAR cginame 1 | var cginame'                                        
       if cginame <> cginame then cgi = cginame                                 
   end                                                                          
   if cgi <> 'CGI' then fn = cgi                                                
end                                                                             
*/                                                                              
                                                                                
Parse var path_translated fn ft fm .                                            
                                                                                
'PIPE command QUERY SEARCH |' ,                                                 
       'locate (15-16) /'fm' / |' ,                                             
       'var disk'                                                               
   Parse var disk . . . . sfsdir .                                              
                                                                                
'CP MSG HARRY MRTDUMP of' fn 'from' sfsdir                                      
                                                                                
src = ''                                                                        
'PIPE VAR sigl 1 | var sigl'                                                    
If sigl <> 'SIGL' Then do                                                       
  'PIPE diskrandom ' fn ft fm sigl '| var srcline'                              
  src = 'Sourceline('sigl'.'rc'):' srcline                                      
end                                                                             
                                                                                
src2 = ''                                                                       
'PIPE VAR errsigl 1 | var errsigl'                                              
If errsigl <> 'ERRSIGL' Then do                                                 
  'PIPE diskrandom ' fn ft fm errsigl '| var srcline'                           
  src2 = 'Error Sourceline('errsigl'.'rc'):' srcline                            
end                                                                             
                                                                                
q = 'Queued:' queued()                                                          
                                                                                
header = 'Dump:' fn ft fm'('sfsdir')' 'Date:' date('S') time() userid()         
'PIPE var header |' ,                                                           
  'append var src |' ,                                                          
  'append var src2 |' ,                                                         
  'append var q |' ,                                                            
  'append literal Variables: |' ,                                               
  ' >' fn oft ofm                                                               
                                                                                
'PIPE REXXVARS 1',                                                              
          '| DROP  FIRST 1',                                                    
          '| SPECS WORD 2-*',                                                   
          '| join /=/' ,                                                        
          '| >>' fn oft ofm                                                     
                                                                                
'PIPE VAR EWEB.AA 1 | var thread'                                               
                                                                                
group = 'HTTPD'                                                                 
'PIPE COMMAND GLOBALV SELECT' group 'LIST | >' fn 'GLOBALV' ofm                 
                                                                                
group = 'THREAD'thread                                                          
'PIPE COMMAND GLOBALV SELECT' group 'LIST | >>' fn 'GLOBALV' ofm                
                                                                                
group = 'COOKIE'thread                                                          
'PIPE COMMAND GLOBALV SELECT' group 'LIST | >>' fn 'GLOBALV' ofm                
                                                                                
group = 'HEADER'thread                                                          
'PIPE COMMAND GLOBALV SELECT' group 'LIST | >>' fn 'GLOBALV' ofm                
                                                                                
'PIPE command QUERY SEARCH | >' fn 'DISK' ofm                                   
                                                                                
exit                                                                            
                                                                                
syntax:                                                                         
                                                                                
'CP MSG HARRY MRTDUMP Syntax error on' sigl                                     
'CP IPL'